[AccessD] Access n Front Page

Tue Jan 13 12:09:09 CST 2004

This is down and dirty, but the following is a relatively simple .asp page,
which displays an .mdb table in HTML format.  You can then edit the values,
and submit it, and it will change the values in the table.  It requires that
you have an ID field (the code is currently set to use field 0 as the ID).

<html>
<%
dim cnn
dim rs
dim i
dim strSQL
dim intCount
if request.Form("Submit")="Submit" then
	set cnn=server.CreateObject("ADODB.Connection")
	set rs=server.CreateObject("ADODB.Recordset")
	cnn.Provider="Microsoft.Jet.OLEDB.4.0"
	cnn.Open "C:\Inetpub\domains\airs\Air2000_be.mdb"
	rs.Open "tblWebFields",cnn,1,3,512	
	intCount=rs.Fields.Count-1
	rs.MoveFirst
	do until rs.EOF=True
		for i=1 to intCount
			rs.Fields(i).value=request.Form(rs.Fields(0).value &
"-" & rs.Fields(i).Name)
		next
		rs.Update
		rs.MoveNext
	loop
	rs.Close
	set rs=nothing
	cnn.Close
	set cnn=nothing
end if
%>
<head>
<title>Dyncorp Field Settings</title>
</head>
<body>
<form name="FieldSettings" method=post>
<input type=submit name="Submit" value="Submit">
<table width="100%" border=1>
<%
set cnn=server.CreateObject("ADODB.Connection")
set rs=server.CreateObject("ADODB.Recordset")
cnn.Provider="Microsoft.Jet.OLEDB.4.0"
cnn.Open "C:\Inetpub\domains\airs\Air2000_be.mdb"
rs.Open "tblWebFields",cnn,1,1,512	
response.Write "<tr>" & vbcrlf
intCount=rs.Fields.Count-1
for i=1 to intCount
	response.Write "<td width=""" & 100/intCount & """>" &
rs.Fields(i).Name & "</td>" & vbcrlf
next
response.Write "</tr>" & vbcrlf
rs.MoveFirst
do until rs.EOF=True
	response.Write "<tr>" & vbcrlf
	for i=1 to intCount
		response.Write "<td width=""" & 100/intCount & """>" &
vbcrlf
		response.Write "<input type=""text"" name=""" &
rs.Fields(0).Value & "-" & rs.Fields(i).Name & """ value=""" &
rs.Fields(i).Value & """></td>" & vbcrlf
	next
	response.Write "</tr>" & vbcrlf
	rs.MoveNext
loop
rs.Close
set rs=nothing
cnn.Close
set cnn=nothing
%>
</table>
<input type=submit name="Submit" value="Submit">
</form>
</body>

-----Original Message-----
From: Bob Heygood [mailto:bheygood at abestsystems.com]
Sent: Tuesday, January 13, 2004 10:08 AM
To: Access Developers discussion and problem solving
Subject: [AccessD] Access n Front Page

Hey to the group,

Hopefully this is not too far off. But so much here now has to do with the
web.

I am looking for some info on editing a record in an Access db from a web
browser using Front Page. I have found enough on displaying records, but not
on editing existing data. I suspect asp or some such will be involved.

best,

bob

_______________________________________________
AccessD mailing list
AccessD at databaseadvisors.com
http://databaseadvisors.com/mailman/listinfo/accessd
Website: http://www.databaseadvisors.com