[AccessD] Getting rid of the Access Background

A.D.Tejpal adtp at touchtelindia.net
Mon Jul 18 06:49:29 CDT 2005


Rocky,

    My sample db named AppointmentsAlert might also be of interest to you. It is available at Rogers Access Library (other developers library). Link - http://www.rogersaccesslibrary.com

    It demonstrates a form (without Access background window) to pop-up on the desktop, providing an audio-visual alert for imminent scheduled appointments (if any). The form materializes on top of other applications that might be in use.

Best wishes,
A.D.Tejpal
--------------

  ----- Original Message ----- 
  From: Gustav Brock 
  To: accessd at databaseadvisors.com 
  Sent: Sunday, July 17, 2005 15:58
  Subject: Re: [AccessD] Getting rid of the Access Background


  Hi Rocky

  I've had better luck with the code from Drew - that from Dev always complained that either a form was missing or was too much - quite confusing.
  Drew's code doesn't have those limitations and works nicely. 
  I modified it slightly:

  Option Compare Database
  Option Explicit

  Const SW_HIDE           As Long = 0
  Const SW_SHOWNORMAL     As Long = 1
  Const SW_SHOWMINIMIZED  As Long = 2
  Const SW_SHOWMAXIMIZED  As Long = 3

  Private Declare Function IsWindowVisible Lib "user32" ( _
    ByVal hwnd As Long) _
    As Long

  Private Declare Function ShowWindow Lib "user32" ( _
    ByVal hwnd As Long, _
    ByVal nCmdShow As Long) _
    As Long

  Public Function fAccessWindow( _
    Optional Procedure As String, _
    Optional SwitchStatus As Boolean, _
    Optional StatusCheck As Boolean) _
    As Boolean

    Dim lngState    As Long
    Dim lngReturn   As Long
    Dim booVisible  As Boolean
    
    MsgBox Application.hWndAccessApp

    If SwitchStatus = False Then
      Select Case Procedure
        Case "Hide"
          lngState = SW_HIDE
        Case "Show", "Normal"
          lngState = SW_SHOWNORMAL
        Case "Minimize"
          lngState = SW_SHOWMINIMIZED
        Case "Maximize"
          lngState = SW_SHOWMAXIMIZED
        Case Else
          lngState = -1
      End Select
    Else
      If IsWindowVisible(hWndAccessApp) = 1 Then
        lngState = SW_HIDE
      Else
        lngState = SW_SHOWNORMAL
      End If
    End If
    
    If lngState >= 0 Then
      lngReturn = ShowWindow(Application.hWndAccessApp, lngState)
    End If

    If StatusCheck = True Then
      If IsWindowVisible(hWndAccessApp) = 1 Then
        booVisible = True
      End If
    End If
    
    fAccessWindow = booVisible

  End Function

  Have in mind that reports cannot be previewed with the MDI hidden.

  /gustav

  >>> bchacc at san.rr.com 07/17 1:45 am >>>
  Dear List:

  I have an app which is an mde and I'd like the forms to appear without the standard access background frame.  Sort of float over the desktop as it were.  The forms have no max, min, and close buttons and no menu or tool bars and border style of dialog.  Any way to do this?

  MTIA,

  Rocky Smolin
  Beach Access Software
  http://www.e-z-mrp.com 
  858-259-4334



More information about the AccessD mailing list