[AccessD] Common error number

Gustav Brock Gustav at cactus.dk
Fri Dec 8 11:51:15 CST 2006


Hi Susan

18

Or create a list for yourself with DAO:

Function AccessAndJetErrorsTable() As Boolean
        
  Dim dbs As Database, tdf As TableDef, fld As Field
  Dim rst As Recordset, lngCode As Long
  Dim strAccessErr As String
  
  Const conAppObjectError = "Unspecified error code"
  
  On Error GoTo Error_AccessAndJetErrorsTable
  
  ' Create Errors table with ErrorNumber and ErrorDescription fields.
  Set dbs = CurrentDb
  Set tdf = dbs.CreateTableDef("AccessAndJetError")
  
  Set fld = tdf.CreateField("ErrorCode", dbLong)
  tdf.Fields.Append fld
  
  Set fld = tdf.CreateField("ErrorString", dbMemo)
  tdf.Fields.Append fld
  
  dbs.TableDefs.Append tdf
  
  ' Open recordset on Errors table.
  Set rst = dbs.OpenRecordset("AccessAndJetErrors")
  ' Loop through error codes.
  For lngCode = 0 To 9999 '3500
    On Error Resume Next
    ' Raise each error.
    strAccessErr = AccessError(lngCode)
    DoCmd.Hourglass True
    ' Skip error numbers without associated strings.
    If strAccessErr <> "" Then
      ' Skip codes that generate application or object-defined errors.
      If strAccessErr <> conAppObjectError Then
        ' Add each error code and string to Errors table.
        rst.AddNew
        rst!ErrorCode = lngCode
        ' Append string to memo field.
        rst!ErrorString.AppendChunk strAccessErr
        rst.Update
      End If
    End If
  Next lngCode
  ' Close recordset.
  rst.Close
  
  DoCmd.Hourglass False
  RefreshDatabaseWindow
  MsgBox "Access and Jet errors table created."

AccessAndJetErrorsTable = True

Exit_AccessAndJetErrorsTable:
  Exit Function

Error_AccessAndJetErrorsTable:
  MsgBox Err & ": " & Err.Description
  AccessAndJetErrorsTable = False
  Resume Exit_AccessAndJetErrorsTable
End Function

/gustav

>>> ssharkins at setel.com 08-12-2006 18:08:14 >>>
I need a common error number for an example using Raise. I can't come up
with one that shows anything interesting! ;) 
 
Susan H. 
-- 
AccessD mailing list
AccessD at databaseadvisors.com 
http://databaseadvisors.com/mailman/listinfo/accessd 
Website: http://www.databaseadvisors.com




More information about the AccessD mailing list